STC32G12K128 单片机 I2C 应用 - DS3231实时时钟

原创 已于 2026-06-28 11:32:22 修改 · 254 阅读 · 5 ·
本内容遵循CC 4.0 BY-SA版权协议
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
GEO检测
标签
#单片机 #嵌入式硬件 #DS3231 #实时时钟 #I2C
#汇编程序
于 2026-06-27 17:36:43 首次发布

目标

此汇编程序实现DS3231 实时时钟 (RTC)，并在 LCD1602 显示年/月/日/星期/时:分:秒。

为了更流畅，本程序只在第一次运行及当时间为00:00:00时才更新 年/月/日/星期，以减低显示屏的工作量，避免秒数不连贯。

网上 DS3231 程序多是用C++ 写成的，本程序反而用汇编语言写成的，一来看看汇编语言是否比较稳定，LCD1602 会不会出现闪烁现象; 二来充实一下STC32G12K128 单片机汇编语言程式库。

I2C 串口通讯简介

DS3231使用 I2C 串口通讯与MCU连接，I2C的好处是线路要求十分简单，只需两条电线。I2C 可以串联多个设备，不会因为增加设备而需要添加 GPIO 端口的数目。

STC32G12K128 单片机内部集成了一个 I2C 串行总线控制器。I2C 是一种高速同步通讯总线, 通讯使用 SCL (串行时钟线) 和 SDA (串行数据线) 两线进行同步通讯。STC32G12K128单片机的I2C总线提供了两种操作模式：主机模式 (SCL 为输出口, 发送同步时钟信号) 和 从机模式 (SCL 为输入口, 接收同步时钟信号), 本程序使用主机模式 (Master State)。

线路图：

执行结果：

设定I2C 功能脚位

P_SW2   地址为 0BAH

I2C_S = 00, SCL 脚位对应P1.5, SDA 脚位对应P1.4。

设定 I2C 总线速度

DS3231 支援总线速度最高为 400Kbps。

I2C 配置寄存器 Configuration Register (I2CCFG)

地址 7EFE80H

ENI2C = 1   允许I2C 功能

MSSL = 1  主机模式

MSSPEED = 13  (二进制1101)

I2C 总线速度 = SYSCLK / 2 / (MSSPEED * 2 + 4)  = 24 MHz / 2 / (13 * 2 + 4 )

                                                                                      = 24000 KHz / 60 = 400 Kbps

由于 I2CCFG 是扩展特殊功能寄存器，逻辑地址位于XDATA 区域内，访问前需要将P_SW2寄存器的最高位 (EAXFR) 置1，然后使用 MOV @DRk, Rm 和MOV Rm, @DRk 指令进行访问，例如：

                MOV     A, #0CDH             ;R11 即是 ACC

                MOV     WR6, #WORD0 I2CCFG

                MOV     WR4, #WORD2 I2CCFG

                MOV     @DR4, R11       ; MOV I2CCFG, #0CDH   使能I2C 主机模式, 总线速度 400K

                ; 受STC32G12K128 寻址方式限制, MOV @DR4, R11 不可以写成 MOV @DR4, A。

I2C Master State Control Register 主机控制寄存器 (I2CMSCR)

地址 7EFE81H

EMSI = 1 允许主机模式的中断

I2C 总线数据通讯协定

MSCMD 主机命令

0.  Idle (待机), 无动作。

1.  Start (起始命令)

2.  Send data (发起数据命令)

3. Recv ACK (接收 ACK 命令)

4. RECV (接收数据命令)

5.Send ACK (发送ACK 命令)

6. Stop (停止命令)

I2C Master State Status Register主机状态寄存器 (I2CMSST)

地址 7EFE82H

MSIF (Master State Interrupt Flag 主机模式中断标志位) 当 I2C 主机完成任务后，MSIF 自动为1，向CPU请求中断，MSIF 位必须软件清0。

MSACKO (Master State Acknowledgement Output) – 发送ACK 命令之后，控制器读取此位的数据当作ACK发送到SDA。

DS3231 寄存器

I2C 地址 68H

地址

寄存器

范围

备注

00

秒

00-59

bit 7 不用, 常是0

01

分

00-59

bit 7不用, 常是0

02

时

01-12 或 00-23

bit 6: 1=12小 时模式, bit 5: 1 = PM

03

星期

1-7

1=星期一, 7 = 星期日

04

日

01-31

05

月

01-12

bit 7 世纪位

06

年

00-99

校准时钟

先计算，偏移量 =    ÷0.1

有效值为  -128 至 +127, 即每天可以调快或调慢1秒左右。

将此偏移量写入Aging offset 寄存器内(地址10H)，如果时钟走慢了, 取负值; 走快了, 取正值。

例如：DS3231 二天快了 2 秒，

偏移量 = ​​​​  ÷ 0.1 = 115

Calibrate:

                CALL      Start                                    ; 发起起始命令

                MOV     A, #0D0H                              ; 发起设置地址 (0x68) + 写命令 (0)

                CALL      SendData

                CALL      RecvACK

                MOV     A, #10H                                 ; 发起存储地址(Aging offset)

                CALL      SendData

                CALL      RecvACK

                MOV     A, #115                                 ; 写数据 115

                CALL      SendData

                CALL      RecvACK

                CALL      STOP                                  ; 发送停止命令

                RET

DS3231 RTC 时钟源码:

$NOMOD51
#include "STC32G.INC"

Fosc_KHZ EQU 24000			; 系统时钟 24 MHz
;========================================================================
; STC32G 测试 DS3231 (I2C) 并显示于 LCD1602
;========================================================================

; --- I2C 引脚定义 ---
I2C_SCL BIT     P1.5		; 串行时钟线
I2C_SDA BIT     P1.4		; 串行数据线 

hours   DATA    30H			; 时 (BCD)
minute  DATA    31H			; 分 (BCD)
second  DATA    32H			; 秒 (BCD)
days    DATA    33H     	; 日 (BCD)
months  DATA    34H     	; 月 (BCD)
years   DATA    35H     	; 年 (BCD)
week    DATA    36H     	; 星期 (1~7) 

first_run DATA  37H     	; 第一次运行标志 (0代表第一次，1代表之后)
	
	ORG 	0000H
	LJMP 	MAIN

	ORG 	0200H
MAIN:
    MOV 	SP, #0C0H

	MOV 	WTST, #0		; CPU 执行程序的速度设置为最快
	MOV 	CKCON, #0		; 设置外部数据总线速度为最快
	ORL 	P_SW2,#080H     ; 使能访问XFR
	MOV 	P0M0, #0		; 准双向口模式
	MOV 	P0M1, #0		; 准双向口模式
	MOV 	P1M0, #030H		; P1.4, P1.5 开漏模式, 需外加上拉电阻
	MOV 	P1M1, #030H		; P1.4, P1.5 开漏模式, 需外加上拉电阻
	MOV 	P2M0, #0		; 准双向口模式
	MOV 	P2M1, #0		; 准双向口模式
	ANL     P_SW2, #0CFH	; I2C_S = 00 SCL 和 SDA 引脚映射至 P1.4 及 P1.5
	MOV     first_run, #0	; 此是第一次运行

;================= 初始化 LCD1602=============================

	LCALL	F_Initialize_LCD
	MOV		A, #0
	LCALL	F_ClearLine
	MOV		A, #1
	LCALL	F_ClearLine

;================= 初始化 I2C ================================
    MOV     A, #0CDH		; R11 即是 ACC, 但不可用 MOV @DR4, A
	MOV     WR6, #WORD0 I2CCFG
	MOV     WR4, #WORD2 I2CCFG
	MOV     @DR4, R11       ; MOV I2CCFG, #0CDH   使能I2C 主机模式, 总线速度 400K
    MOV     A, #0
	MOV     WR6, #WORD0 I2CMSST
	MOV     WR4, #WORD2 I2CMSST
	MOV     @DR4, R11       ; MOV I2CMSST, #0   I2CMSST 寄存器清零 

    JMP     DISP			; 此行前如果加 ; 设定年/月/日/星期/时/分/秒

;================= 设置 DS3231 时间 ==========================

	CALL	Start			; 发起起始命令
	MOV		A, #0D0H		; 发起设置地址 (0x68) + 写命令 (0)
	CALL	SendData
	CALL	RecvACK
	MOV		A, #0			; 发起存储地址(秒)
	CALL	SendData
	CALL	RecvACK
	MOV		A, #0			; 写数据 0秒 (BCD)
	CALL	SendData
	CALL	RecvACK
	MOV		A, #15H			; 写数据 15分 (BCD)
	CALL	SendData
	CALL	RecvACK
	MOV		A, #14H			; 写数据 14时 (BCD)
	CALL	SendData
	CALL	RecvACK
	
	MOV     A, #06H         ; 星期六 (1=Mon, 2=Tue... 6=Sat, 7=Sun)
    CALL    SendData
    CALL    RecvACK
    MOV     A, #27H         ; 27日 (BCD)
    CALL    SendData
    CALL    RecvACK
    MOV     A, #06H         ; 06月 (BCD)
    CALL    SendData
    CALL    RecvACK
    MOV     A, #26H         ; 26年 (2026年 BCD)
    CALL    SendData
    CALL    RecvACK
	
	CALL	STOP			; 发送停止命令
	CALL    Delay			; 等待设备写数据
	
;================= 显示 DS3231 时间 ==========================
DISP:
	;--- 1. 每次都读取 时、分、秒 ---
	CALL	Start			; 发起起始命令
	MOV		A, #0D0H		; 发起设置地址 (0x68) + 写命令 (0)
	CALL	SendData
	CALL	RecvACK
	MOV		A, #0			; 发起存储地址(秒)
	CALL	SendData
	CALL	RecvACK
	CALL	Start			; 发起起始命令
	MOV		A, #0D1H		; 发起设置地址 (0x68) + 读命令 (1)
	CALL	SendData
	CALL	RecvACK
	CALL	RecvData		; 读取数据 (秒)
	MOV		second, A
	CALL	SendACK
	CALL	RecvData		; 读取数据 (分)
	MOV		minute, A
	CALL	SendACK
	CALL	RecvData		; 读取数据 (时)
	MOV		hours, A
	CALL	SendNAK
	CALL	STOP			; 发送停止命令
	CALL	DisplayRTC		; 在 LCD1602 显示时分秒
	
	;--- 2. 判断是否需要更新第 1 行 (年月日星期) ---
    MOV     A, first_run
    JZ      UPDATE_YMD      ; 如果第一次运行 first_run == 0，必須更新
    
    ; 检查是否为 00:00:00
    MOV     A, second
    JNZ     SKIP_YMD        ; 秒 != 0，跳过
    MOV     A, minute
    JNZ     SKIP_YMD        ; 分 != 0，跳过
    MOV     A, hours
    JNZ     SKIP_YMD        ; 时 != 0，跳过

UPDATE_YMD:
    MOV     first_run, #1   ; 标记已经执行过第一次了
    
    ;--- 3. 读取 DS3231 的星期、日、月、年 (地址 03H~06H) ---
    CALL    Start           ; 发起起始命令
    MOV     A, #0D0H        ; 发起设置地址 (0x68) + 写命令 (0)
    CALL    SendData
    CALL    RecvACK
    MOV     A, #03H         ; 从 03H (星期) 开始读
    CALL    SendData
    CALL    RecvACK
    CALL    Start           ; 发起起始命令   
    MOV     A, #0D1H        ; 发起设置地址 (0x68) + 读命令 (1)        
    CALL    SendData
    CALL    RecvACK
    CALL    RecvData        ; 读取 星期
    MOV     week, A
    CALL    SendACK
    CALL    RecvData        ; 读取 日
    MOV     days, A
    CALL    SendACK
    CALL    RecvData        ; 读取 月
    MOV     months, A
    CALL    SendACK
    CALL    RecvData        ; 读取 年
    MOV     years, A
    CALL    SendNAK
    CALL    STOP
    
    CALL    DisplayYMD      ; 调用函数：刷新 LCD 第 1 行

SKIP_YMD:
    CALL    Delay           ; 延時 150ms
	JMP		DISP			; 不断循环
	
;================= I2C 程序库 ==========================
Wait: 
	MOV     WR6,#WORD0 I2CMSST
	MOV     WR4,#WORD2 I2CMSST
	MOV     R11,@DR4		; MOV A, I2CMSST
	JNB 	ACC.6, Wait 	; 等待直至中断标志位(MSIF) 为 1
	; 清除中断标志位(MSIF), 其他位元不变
	ANL 	A, #0BFH 		; 屏蔽 bit 6 (0xBF = ~0x40) 
	MOV     WR6, #WORD0 I2CMSST
	MOV     WR4, #WORD2 I2CMSST
	MOV     @DR4, R11       ; MOV I2CMSST, A    写入 I2CMSST
	RET 

Start:
    MOV     A, #1			; 发送 Start 命令
	MOV     WR6, #WORD0 I2CMSCR
	MOV     WR4, #WORD2 I2CMSCR
	MOV     @DR4, R11       ; MOV I2CMSCR, #1
	CALL	Wait
	RET

SendData:
	MOV     WR6, #WORD0 I2CTXD
	MOV     WR4, #WORD2 I2CTXD
	MOV     @DR4, R11       ; MOV I2CTXD, A  (由 ACC 发送数据到 TX buffer)
    MOV     A, #2			; 发送 Send 命令
	MOV     WR6, #WORD0 I2CMSCR
	MOV     WR4, #WORD2 I2CMSCR
	MOV     @DR4, R11       ; MOV I2CMSCR, #2
	CALL 	Wait		
	RET

RecvACK:
    MOV     A, #3			; 发送 接收 ACK 命令
	MOV     WR6, #WORD0 I2CMSCR
	MOV     WR4, #WORD2 I2CMSCR
	MOV     @DR4, R11       ; MOV I2CMSCR, #3
	CALL 	Wait
	RET

RecvData:
    MOV     A, #4			; 发送 RECV 命令
	MOV     WR6, #WORD0 I2CMSCR
	MOV     WR4, #WORD2 I2CMSCR
	MOV     @DR4, R11       ; MOV I2CMSCR, #4
	CALL 	Wait
	MOV     WR6, #WORD0 I2CRXD
	MOV     WR4, #WORD2 I2CRXD
	MOV     R11, @DR4		; MOV A, I2CRXD (由 RX buffer 接收数据到 ACC)
	RET

SendACK:
	MOV     WR6, #WORD0 I2CMSST
	MOV     WR4, #WORD2 I2CMSST
	MOV     R11, @DR4		; MOV A, I2CMSST
	ANL		A, #0FEH		; ACK 信号 0 到 SDA
    MOV     @DR4, R11	
    MOV     A, #5			; 发送 ACK 命令
	MOV     WR6, #WORD0 I2CMSCR
	MOV     WR4, #WORD2 I2CMSCR
	MOV     @DR4, R11       ; MOV I2CMSCR, #5
	CALL 	Wait
	RET

SendNAK:
	MOV     WR6, #WORD0 I2CMSST
	MOV     WR4, #WORD2 I2CMSST
	MOV     R11, @DR4		; MOV A, I2CMSST
	ORL		A, #1			; NAK 信号 1 到 SDA
    MOV     @DR4, R11	
    MOV     A, #5			; 发送 ACK 命令
	MOV     WR6, #WORD0 I2CMSCR
	MOV     WR4, #WORD2 I2CMSCR
	MOV     @DR4, R11       ; MOV I2CMSCR, #5
	CALL 	Wait
	RET

Stop:
    MOV     A, #6			; 发送 STOP 命令
	MOV     WR6, #WORD0 I2CMSCR
	MOV     WR4, #WORD2 I2CMSCR
	MOV     @DR4, R11       ; MOV I2CMSCR, #6
	CALL	Wait
	RET

;========================================================================
; 函数: F_DisplayRTC
; 描述: 显示时钟函数
; 参数: none.
; 返回: none.
;========================================================================
DisplayRTC:
	    MOV		R2, #1	            ;第2行     (第一行是 '0')
		MOV		R3, #4				;第4个字符 (最左是 '0')
		MOV		A, hours
		MOV		B, A
		SWAP	A
		ANL		A, #0FH				; 时十位
		ADD		A, #'0'				;(2,5,hours / 10 + '0')
		LCALL	F_WriteChar
		INC		R3					;第5个字符
		MOV		A, B				; B = 时个位
		ANL		A, #0FH				
		ADD		A, #'0'				;(2,6,hours % 10 +'0')
		LCALL	F_WriteChar
		INC		R3					;第6个字符
		MOV		A, #':'				;(2,7,':')
		LCALL	F_WriteChar

		INC		R3					;第7个字符
		MOV		A, minute
		MOV		B, A
		SWAP	A
		ANL		A, #0FH				; 分十位
		ADD		A, #'0'				;(2,8,hours / 10 + '0')
		LCALL	F_WriteChar
		INC		R3					;第8个字符
		MOV		A, B				; B = 分个位
		ANL		A, #0FH				
		ADD		A, #'0'				;(2,9,minute % 10 +'0')
		LCALL	F_WriteChar
		INC		R3					;第9个字符
		MOV		A, #':'				;(2,10,':')
		LCALL	F_WriteChar

		INC		R3					;第10个字符
		MOV		A, second
		MOV		B, A
		SWAP	A
		ANL		A, #0FH				; 秒十位
		ADD		A, #'0'				;(2,11,second / 10 + '0')
		LCALL	F_WriteChar
		INC		R3					;第11个字符
		MOV		A, B				; B = 秒个位
		ANL		A, #0FH				
		ADD		A, #'0'				;(2,12,second % 10 +'0')
		LCALL	F_WriteChar
		RET

;========================================================================
; 函数: DisplayYMD
; 描述: 在LCD1602第1行显示 年/月/日 星期 (例如: 2026/06/27 Sat)
;========================================================================
DisplayYMD:
        MOV     R2, #0              ; 第 1 行 (暂存器为0)
        MOV     R3, #1              ; 从第 1 个字元开始写
        
        ; 固定显示 "20"
        MOV     A, #'2'
        LCALL   F_WriteChar
        INC     R3
        MOV     A, #'0'
        LCALL   F_WriteChar
        INC     R3
        
        ; 显示 年 (year)
        MOV     A, years
        MOV     B, A
        SWAP    A
        ANL     A, #0FH
        ADD     A, #'0'
        LCALL   F_WriteChar         ; 年十位
        INC     R3
        MOV     A, B
        ANL     A, #0FH
        ADD     A, #'0'
        LCALL   F_WriteChar         ; 年个位
        INC     R3
        
        MOV     A, #'/'             ; 分隔符
        LCALL   F_WriteChar
        INC     R3
        
        ; 显示 月 (month)
        MOV     A, months
        MOV     B, A
        SWAP    A
        ANL     A, #0FH
        ADD     A, #'0'
        LCALL   F_WriteChar         ; 月十位
        INC     R3
        MOV     A, B
        ANL     A, #0FH
        ADD     A, #'0'
        LCALL   F_WriteChar         ; 月个位
        INC     R3
        
        MOV     A, #'/'             ; 分隔符
        LCALL   F_WriteChar
        INC     R3
        
        ; 显示 日 (day)
        MOV     A, days
        MOV     B, A
        SWAP    A
        ANL     A, #0FH
        ADD     A, #'0'
        LCALL   F_WriteChar         ; 日十位
        INC     R3
        MOV     A, B
        ANL     A, #0FH
        ADD     A, #'0'
        LCALL   F_WriteChar         ; 日个位
        INC     R3
        
        MOV     A, #' '             ; 空格
        LCALL   F_WriteChar
        INC     R3

        ; --- 显示星期字串 ---
        ; 根据 week (1~7) 计算字串查表偏移量。每个字串含结尾0共4字节 (week * 4)
		MOV     A, week
        ANL     A, #07H             ; 安全遮罩
        ADD     A, ACC              ; A = week * 2
        ADD     A, ACC              ; A = week * 4
        MOV     DPTR, #String_Week
        ADD     A, DPL
        MOV     DPL, A
        MOV     A, #0
        ADDC    A, DPH
        MOV     DPH, A              ; DPTR 现在指向对应星期的字串首地址
        
        ; 呼叫 F_PutString 来显示星期
        LCALL   F_PutString 
        RET
		
Delay:								;延时150ms
		MOV		A, #150
F_delay_ms:
		PUSH    02H     			;入栈R2
		PUSH    03H     			;入栈R3
		PUSH    04H     			;入栈R4

		MOV     R4, A   			; 将传递回来的毫秒数(A)赋给外层循环计数器R4

L_delay_ms_1:
		MOV     WR2, #(Fosc_KHZ / 5)    ; 1T, WR2 = 4800 (使每轮循环耗时1ms)
    
L_delay_ms_2:
		DEC     WR2, #1         	; 1T
		JNE     L_delay_ms_2    	; 3/4T    4799*5 + 4 = 23,999T

		DJNZ    R4, L_delay_ms_1    ; 1/3T    (Acc-1)*24,003 + 24000T 	    

		POP     04H     ;出栈R4
		POP     03H     ;出栈R3
		POP     02H     ;出栈R2
		RET
	
;*************	LCD1602 驱动 **************

;8位数据访问方式	LCD1602		

LineLength	EQU	16		;16x2

/*************	定义脚位	**************************************/

LCD_BUS 	DATA P0		;P0--0x80, P1--0x90, P2--0xA0, P3--0xB0

LCD_B7  BIT LCD_BUS.7	;D7 -- Pin 14		LED- -- Pin 16 
LCD_B6  BIT LCD_BUS.6	;D6 -- Pin 13		LED+ -- Pin 15
LCD_B5  BIT LCD_BUS.5	;D5 -- Pin 12		Vo   -- Pin 3
LCD_B4  BIT LCD_BUS.4	;D4 -- Pin 11		VDD  -- Pin 2
LCD_B3  BIT LCD_BUS.3	;D3 -- Pin 10		VSS  -- Pin 1
LCD_B2  BIT LCD_BUS.2	;D2 -- Pin  9
LCD_B1  BIT LCD_BUS.1	;D1 -- Pin  8
LCD_B0  BIT LCD_BUS.0	;D0 -- Pin  7

LCD_ENA	BIT P2.7	;Pin 6
LCD_RW	BIT P2.6	;Pin 5   LCD_RS  R/W  DB7--DB0  功能
LCD_RS	BIT P2.5	;Pin 4		0	 0     输入     写入命令
					;			0	 1     输出     读取 BF 和 AC 指针数据
					;			1	 0     输入     写入数据
					;			1	 1     输出     读取数据

;共两行, 16x2= 32 (内部显存一行有40个字符)
;第一行位址:  0~15
;第二行位址: 64~79

;指令集
; ==================== 1. 基本指令 ====================
C_CLEAR         EQU 0x01    ; 清屏 (光标归零，DDRAM填满空格)
C_HOME          EQU 0x02    ; 归位 (光标归零，画面不改变)

; ==================== 2. 输入模式设置 (Entry Mode) ====================
C_CUR_L         EQU 0x04    ; 输入后：光标左移，画面不动
C_DISP_R        EQU 0x05    ; 输入后：光标左移，画面【右】平移
C_CUR_R         EQU 0x06    ; 输入后：光标右移，画面不动 (最常用)
C_DISP_L        EQU 0x07    ; 输入后：光标右移，画面【左】平移 (滚动字幕效果)

; ==================== 3. 显示/光标开关控制 ====================
C_OFF           EQU 0x08    ; 关闭 LCD 显示
C_ON            EQU 0x0C    ; 开启 LCD, 无光标, 不闪烁
C_FLASH         EQU 0x0D    ; 开启 LCD, 无光标, 仅光标所在位置闪烁 
C_CURSOR        EQU 0x0E    ; 开启 LCD, 有光标, 不闪烁
C_FLASH_ALL     EQU 0x0F    ; 开启 LCD, 有光标, 且光标闪烁

; ==================== 4. 光标/画面位移 (不影响DDRAM) ====================
C_CURSOR_LEFT   EQU 0x10    ; 仅将光标向左平移一个字符位
C_CURSOR_RIGHT  EQU 0x14    ; 仅将光标向右平移一个字符位
C_PICTURE_LEFT  EQU 0x18    ; 将整个画面向左平移一个字符位
C_PICTURE_RIGHT EQU 0x1C    ; 将整个画面向右平移一个字符位

; ==================== 5. 功能设置 (Function Set) ====================
C_BIT4          EQU 0x20    ; 4位总线，1行显示，5x7点阵
C_4bitL2DOT7    EQU 0x28    ; 4位总线，2行显示，5x7点阵 (4位模式最常用)
C_BIT8          EQU 0x30    ; 8位总线，1行显示，5x7点阵
C_L1DOT10       EQU 0x34    ; 8位总线，1行显示，5x10点阵
C_L2DOT7        EQU 0x38    ; 8位总线，2行显示，5x7点阵 (8位模式最常用)

; ==================== 6. 地址设置 ====================
C_CGADDRESS0    EQU 0x40    ; CGRAM 起始位址 (存储自定义字符，后面加偏移量 0~63)
C_DDADDRESS0    EQU 0x80    ; DDRAM 起始位址 (屏幕显示坐标，第一行0x80+x，第二行0xC0+x)

;========================================================================
; 函数: F_LCD_DelayNop
; 描述: 延时函数
; 参数: none.
; 返回: none.
;========================================================================
F_LCD_DelayNop:
	NOP			;NOP(15T)
	NOP
	NOP
	NOP
	NOP
	NOP
	NOP
	NOP
	NOP
	NOP
	NOP
	NOP
	NOP
	NOP
	NOP
	RET

;========================================================================
; 函数: F_CheckBusy
; 描述: 检测忙 (有超时)
;       物理时序: RS=0, RW=1, E=1 -> 读LCD_B7 -> E=0
; 参数: none.
; 返回: none.
;========================================================================
F_CheckBusy:					
	PUSH	ACC
	PUSH	R2
	PUSH	R3
	MOV		R2, #HIGH 5000 		;设置超时计数器
	MOV		R3, #LOW  5000

L_CheckBusyLoop:
    MOV     LCD_BUS, #0FFH      ; 读准双向口前，必须先将端口置1
    CLR	    LCD_RS				; RS=0 读状态
    SETB	LCD_RW				; RW=1 读操作
	SETB	LCD_ENA				; E脉冲拉高
    LCALL	F_LCD_DelayNop		; 稍微延时让电平稳定
	MOV	    A, LCD_BUS			; 读取 LCD 总线端口状态
	CLR	    LCD_ENA				; E脉冲拉低，完成一次读周期

	JNB	    LCD_B7, L_QuitCheckBusy		; 5T, 如果 LCD_B7(BF) == 0，代表不忙，跳出
    
	; 超时处理逻辑
	MOV	    A, R3				; 1T
	CLR	    C	 			    ; 1T
	SUBB	A, #1				; 2T
	MOV	    R3, A				; 1T
	MOV	    A, R2				; 1T
	SUBB	A, #0				; 2T
	MOV	    R2, A				; 1T
	ORL	    A, R3				; 1T
	JNZ	    L_CheckBusyLoop		; 4T	若未超时则继续检测
	
L_QuitCheckBusy:
	POP	    R3
	POP	    R2
	POP	    ACC
	RET

;========================================================================
; 函数: F_IniSendCMD
; 描述: 初始化写命令(不检测忙)
; 参数: ACC: 要写的命令.
; 返回: none.
;========================================================================
F_IniSendCMD:
	CLR		LCD_RW					; RW=0: 写
	MOV		LCD_BUS, A				; 将命令数据送到总线
	LCALL	F_LCD_DelayNop
	SETB	LCD_ENA					; E 产生正脉冲
	LCALL	F_LCD_DelayNop
	CLR		LCD_ENA
	MOV		LCD_BUS, #0xFF			; 释放总线
	RET

;========================================================================
; 函数: F_Write_CMD
; 描述: 写命令 (先测忙，再写入)
; 参数: ACC: 要写的命令.
; 返回: none.
;========================================================================
F_Write_CMD:
	LCALL	F_CheckBusy				; 确保 LCD 当前处于空闲状态
	
	CLR		LCD_RS					; RS=0: 命令
	CLR		LCD_RW					; RW=0: 写
	MOV		LCD_BUS, A				; 将命令数据送到总线
	LCALL	F_LCD_DelayNop
	SETB	LCD_ENA					; E 产生正脉冲
	LCALL	F_LCD_DelayNop
	CLR		LCD_ENA
	MOV		LCD_BUS, #0xFF			; 释放总线
	RET

;========================================================================
; 函数: F_Write_DIS_Data
; 描述: 写显示数据 (先测忙，再写入)
; 参数: ACC: 要写的数据.
; 返回: none.
;========================================================================
F_Write_DIS_Data:
	LCALL	F_CheckBusy				; 确保 LCD 当前处于空闲状态
	
	SETB	LCD_RS					; RS=1: 数据 (区别于写命令的关键)
	CLR		LCD_RW					; RW=0: 写
	MOV		LCD_BUS, A				; 将字符ASCII码送到总线
	LCALL	F_LCD_DelayNop
	SETB	LCD_ENA					; E 产生正脉冲
	LCALL	F_LCD_DelayNop
	CLR		LCD_ENA
	MOV		LCD_BUS, #0xFF			; 释放总线
	RET

;========================================================================
; 函数: F_Initialize_LCD
; 描述: 初始化LCD函数
; 参数: none.
; 返回: none.
;========================================================================
F_Initialize_LCD:
	CLR 	LCD_ENA
	CLR		LCD_RS
	CLR		LCD_RW

	MOV		A, #15
	LCALL	F_delay_ms				;LCD上电需要至少15ms的稳定时间

	MOV		A, #C_BIT8				;8位元模式 (不测忙)
	LCALL	F_IniSendCMD

	MOV		A, #5
	LCALL	F_delay_ms
	
	MOV		A, #C_BIT8				;再发送多一次8位元模式 (不测忙)
	LCALL	F_IniSendCMD

	MOV		A, #C_L2DOT7			;两行显示，5*7 点阵字符
	LCALL	F_Write_CMD
	MOV		A, #C_CLEAR				;清屏
	LCALL	F_Write_CMD
	MOV		A, #C_CUR_R				;光标向右移动一个字符位
	LCALL	F_Write_CMD
	MOV		A, #C_ON				;开启 LCD
	LCALL	F_Write_CMD
	RET


;========================================================================
; 函数: F_ClearLine
; 描述: 清除1行
; 参数: ACC: 行(0或1)
; 返回: none.
;========================================================================
F_ClearLine:
	MOV		C, ACC.0
	MOV		ACC.6, C
	ANL		A, #0x40
	ORL		A, #0x80
	LCALL	F_Write_CMD				;写命令 (0x80)

	PUSH	R2
	MOV		R2, #LineLength
L_ClearLine_Loop:
	MOV		A, #' '
	LCALL	F_Write_DIS_Data
	DJNZ	R2, L_ClearLine_Loop
	POP		R2
	RET


;========================================================================
; 函数: F_WriteChar
; 描述: 指定行、列和字符, 写一个字符
; 参数: R2: 行(0或1),  R3: 第几个字符(0~15),  ACC: 要写的字符.
; 返回: none.
;========================================================================
F_WriteChar:
	PUSH	ACC

	MOV		A, R2
	MOV		C, ACC.0
	MOV		ACC.6, C
	ANL		A, #0x40
	ORL		A, #0x80
	ADD		A, R3
	LCALL	F_Write_CMD				;写命令 (0x80)
	POP		ACC
	LCALL	F_Write_DIS_Data
	RET

;========================================================================
; 函数: F_PutString
; 描述: 写一个字符串，指定行、列和字符串首地址
; 参数: R2: 行(0或1),  R3: 第几个字符(0~15),  DPTR: 要写的字符串首地址.
; 返回: none.
;========================================================================
F_PutString:
	MOV		A, R2
	MOV		C, ACC.0
	MOV		ACC.6, C
	ANL		A, #0x40
	ORL		A, #0x80
	ADD		A, R3
	LCALL	F_Write_CMD				;写命令 (0x80)
L_PutString_Loop:
	CLR		A
	MOVC	A, @A+DPTR
	JZ		L_QuitPutString			;遇到停止符0结束
	LCALL	F_Write_DIS_Data
	INC		DPTR
	INC		R3
	MOV		A, R3
	CJNE	A, #LineLength, L_PutString_Loop
L_QuitPutString:
	RET

;******************** LCD1602 驱动程序完 ***************************
; 星期字串
String_Week:
    DB  "   ", 0  ; 0 (不用)
    DB  "Mon", 0  ; 1
    DB  "Tue", 0  ; 2
    DB  "Wed", 0  ; 3
    DB  "Thu", 0  ; 4
    DB  "Fri", 0  ; 5
    DB  "Sat", 0  ; 6
    DB  "Sun", 0  ; 7
		
	END

CYLAM2025
关注
＜STC32G12K128入门第六节＞硬件I2C DS321SN进行I2C实战
sinat_58149788的博客
08-24 969
本次我们讲I2C协议，并且已DS3231SN时钟芯片进行实战。I2C其实很简单，主要能读懂手册和时序图。
＜STC32G12K128入门第二十三步＞STC32G驱动AHT10温湿度传感器（含代码）
sinat_58149788的博客
06-29 437
AHT10温湿度传感器驱动指南 摘要：本文介绍了AHT10数字温湿度传感器的驱动方法，采用I²C通信接口，包含硬件连接要点和软件实现代码。该传感器测量范围广（温度-40°C~+85°C，湿度0%~100%RH），精度高（±0.5°C，±3%RH），适用于环境监测等场景。硬件需注意SDA/SCL上拉电阻和电源滤波，软件提供完整I2C驱动和AHT10操作函数，包括初始化、数据读取等。实测代码可直接应用于STC32G等MCU平台。
基于51单片机和OLED12864、DS3231、独立按键的万年历可调时钟
gantengsheng的博客
03-28 1104
万年历可调时钟，STC32G12K128，DS3231，OLED12864，天干地支，农历日期，生肖，温度，节气，节日，独立按键。
基于51单片机与WS2812B彩屏的智能农历时钟设计：红外遥控+DS3231高精度计时
yhn45678901的博客
02-07 1016
本文详细介绍了基于51单片机与WS2812B彩屏的智能农历时钟设计方案，集成了DS3231高精度计时芯片和红外遥控功能。项目实现了精准的农历日期、节气显示与温度监测，通过硬件选型、系统架构和低功耗设计，为电子爱好者提供了完整的DIY指南与优化实践。
玩转51单片机（汇总）
gantengsheng的博客
11-07 4933
51单片机 汇总
时钟芯片闹钟中断不触发的原因解析！
2601_95558093的博客
06-23 216
低温、低电压单独测试电池供电，排除压降驱动不足。电池电压低于芯片最低工作阈值时，计时电路勉强运行，但中断驱动模块供电不足，无法输出有效电平，故障仅在电池使用后期出现，前期测试完全正常。时钟芯片中断引脚为开漏输出，无法直接输出高电平触发主控，不上拉时引脚电平悬浮，MCU无法识别电平变化，4.7kΩ电阻为通用选型，几十kΩ大阻值会拖慢信号响应速度，偶尔错过闹钟时序。多闹钟功能存在使用误区，部分芯片两路闹钟共用同一输出引脚，时间接近时信号重叠，一路闹钟无法触发，软件增加寄存器读取逻辑，区分两路闹钟分别处理动作。
Havenlon 工程集：一步一步构建开源硬件签名设备（Open Hardware Signing Device）— Step 5：MCU 与系统关键模块
wanglin831025的博客
06-24 242
本项目Step5阶段聚焦构建MCU最小系统，为设备赋予基础执行能力。在完成OLED显示和安全芯片接口（Step4）的基础上，本阶段通过STM32L476RET6主控芯片搭建系统核心，包含电源结构、调试接口（SWD/UART）、时钟系统（8MHz晶振）、复位电路及去耦网络等关键模块。该设计确保系统具备稳定计算能力与外设调度基础，但仍处于硬件原型阶段（未实现完整固件功能）。下一阶段（Step6）将进行固件开发，建立显示驱动、安全通信协议和任务调度等系统级功能。当前系统仅用于学习研究，不具备生产级安全性能。
029、中断系统深入：NVIC配置、中断优先级、嵌套与临界区保护
Jack010110的博客
06-23 312
深入理解NVIC配置：嵌入式开发中的中断系统关键要点 本文通过一个工业数据采集器的故障案例，剖析了嵌入式系统中中断处理的核心技术要点。作者详细讲解了NVIC中断控制器的工作原理，包括中断使能/除能、优先级配置和分组策略等关键配置方法，并指出常见陷阱如频繁调用中断使能函数会显著增加延迟。 文章重点分析了中断优先级分组的选择策略（工业控制推荐组2，消费电子推荐组3）以及中断嵌套带来的资源竞争风险，提出了原子操作和临界区保护两种解决方案。特别强调了临界区保护的三种实现方式及其适用场景，其中保存并恢复中断状态的方法
瑞芯微RV1126B开发板（EASY-EAI-PI2） GPIO
EASY_EAI的博客
06-25 264
gpiod库：需要使用上表的【Chip对象名】和【Line偏移量】。sysfs访问方式：需要使用上表的【GPIO系统节点路径】。
高端制造 半导体数字芯片（CPU/GPU/MCU）纯技术管理晋升线（直达 CTO 完整岗位阶梯）
jgy1968的博客
06-23 496
负责项目排期、人力招聘、绩效考核、项目成本、跨部门对接（IP、工艺、产品）。参与公司经营战略，规划 2～5 代芯片长期技术路线，主导先进工艺（7/5/3nm）落地，对接大客户、投资人、供应链高层。制定芯片年度研发路线图，管控流片预算、多项目并行风险，对接晶圆厂、IP 供应商，解决跨产品线技术冲突。高级副总裁 SVP 研发 / 研发中心总经理 多业务线整合管理，除硬件芯片外，纳入编译器、驱动、固件、底层软件团队；，不含纯架构专家线，标注岗位权责、团队规模、从业年限、对应芯片业务定位。
MCU引脚电压恒定原理、钳位机制与烧毁原因完整总结 MCU正常使用的IO口输出高电平永远稳定3.3V、低电平永远稳定0V
2301_80317247的博客
06-24 239
MCU IO电压稳定在3.3V/0V，是内部MOS在额定电流内低阻硬接电源和地实现的硬件钳位；一旦电流超载，MOS内阻升高产生分压，电压就会偏移，持续超载最终过热烧毁IO口。
EXTI 外部中断 + NVIC 中断笔记 STM32 标准库实现
bug_love的博客
06-25 90
│ EXTI 外部中断配置完整流程 ││ ││ 1. main() 最开始 ││ NVIC_PriorityGroupConfig(NVIC_PriorityGroup_2) ← 只调一次 ││ ││ 2. 使能时钟 ││ RCC_APB2Periph_GPIOx + RCC_APB2Periph_AFIO ← AFIO 必须！││ ││ 3. GPIO 配置 ││ GPIO_Mode_IPU（上拉输入）或 GPIO_Mode_IN_FLOATING（浮空） ││ │。
IOS + QT + Purple Pi OH RK3566 实现远程开关灯泡功能
Android小码家
06-23 112
本文展示了一个基于UDP通信的嵌入式系统实现方案，采用Qt5框架开发，工具链包含Xcode、VSCode、Hermes和QtCreator，支持通过MobaXTerm进行Qt应用投屏。系统实现了GPIO控制（引脚15设置为输出模式）和UDP服务端（监听端口10001），运行日志显示存在OpenGL驱动加载问题。项目提供了硬件规格书（附PDF链接）和实现效果图，作者表示可协助完成毕设开发。方案适用于需要远程设备控制和数据传输的嵌入式应用场景。
寄存器映射
最新发布
2502_94639226的博客
06-28 127
寄存器映射就是：STM32 把 GPIO、RCC、USART、TIM 等外设内部的控制寄存器，统一分配到固定地址，CPU 通过读写这些地址来控制硬件。CPU 通过读写这些地址，就能控制外设。如果没有 volatile，编译器可能认为这个值不会变，就不重新读取，程序可能出错。在 STM32 里，寄存器不是普通变量，而是控制硬件的特殊存储单元。比如控制 GPIO、定时器、串口，本质上都是在操作寄存器。外设寄存器地址 = 外设基地址 + 寄存器偏移地址。把外设里的每个寄存器，对应到一个固定的内存地址。
CC-M100LLAT硬件替代FS32K144，车规100脚MCU，支持ISO-26262
AUTO_15075675965的博客
06-24 184
CC-M100LLAT是一款车规级100引脚MCU，采用32位RISC-V内核（RV32IMCFV指令集），主频达80MHz，支持硬件乘除法和浮点运算。配备16KB DTCM、8KB ITCM及1024KB双Bank Flash（支持OTA），64KB数据存储和独立SRAM空间（64KB+32KB），具有全域存储保护和ECC校验。工作电压2.7-5.5V，支持三种低功耗模式，内置多时钟源（8/48MHz RC、PLL至100MHz）及看门狗。符合ISO 26262功能安全标准，适用于汽车电子等高可靠性场景。
433/315MHz无线通讯发射芯片 XL4456，简单易用、高性能的射频IC
2403_86663987的博客
06-26 193
XL4456是一款专为315MHz和433MHz频段设计的低功耗、高性能无线发射芯片。它的核心作用是把数字信号转换成无线电波发射出去，常用于各种遥控器和无线传感器。芯片内部集成了PLL（频率合成器）和PA（功率放大器），外部只需连接晶振、几个电阻电容和一个电感，就能搭建完整的发射电路。XL4456采用SOT23-6L封装，体积小巧，适合体积较小产品。XL4456在315/433MHz应用领域非常广泛，主要用于各种短距离无线遥控和数据传输场景。
NTP协议深度解析数据包结构 · 同步算法 · Windows平台原生C/C++实现
skjie的博客
06-22 374
NTP协议深度解析
W55MH32L-EVB 上手测评：硬件 TCP/IP 加持的以太网单片机，MicroPython 零门槛开发
weixin_44719294的博客
06-22 264
WIZnet推出的W55MH32L-EVB开发板集成了Cortex-M3内核、硬件TCP/IP协议栈、MAC与PHY，大幅降低物联网开发门槛。板载资源丰富，包括温湿度传感器、EEPROM、SD卡插槽等，并支持MicroPython开发，简化了外设控制与网络通信的实现。本文详细介绍了芯片规格、开发板资源及MicroPython开发环境搭建，为硬件物联网项目提供了全面的入门参考。
基于单片机的数字示波器设计
m0_74026776的博客
06-22 195
摘要 本文设计了一种基于STM32F103C8单片机的数字存储示波器系统，针对传统模拟示波器在存储、分析和便携性方面的不足，提出了一种集信号采集、处理与显示于一体的解决方案。系统硬件由电阻衰减电路、带偏置放大电路、频率检测模块、TFT液晶显示模块及电源管理电路等组成，通过STM32实现信号调理、ADC采样与数据处理，支持波形缩放、平移及边沿触发功能。软件设计采用C语言编程，实现了数据采集、插值运算和实时显示。测试结果表明，该系统运行稳定，测量精度高，响应速度快，具有实用性和扩展性，为低成本数字示波器开发提供
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值